(*********************************************************************************
* Copyright: Bernecker+Rainer
* Author:    Mikael Regard
* Created:   May 13, 2019/8:21 AM 
* Updated:   Aug 19, 2019/09:00 AM
 *********************************************************************************
 * Description:
 * FuB to Get mover properties.
 * 
 *Input:
 * MsgFrame  (Profinet output frame)
 * ReadFrame (Profinet reply frame)
 * Execute   (Edgepos, Execute = TRUE will run the FuB once)
 * Cmd Label (Optional 2 byte Command label. Used to identify specfic commands.
 * Xbot ID   (Any positive integer represent a particular Xbot.)
 *
 * Output:
 * Error (Indicates if there is an error)
 * Busy  (FuB will be Busy until reply)
 * Done  (When Accepted command is received, Done = TRUE)
 * MoverType (Mover Type)
 * PayloadWeight (Payload Weight g)
 * UserConfigCG  (User configured Center of Gravity mm)
 * XMoverDim (Mover dimension in X mm)
 * YMoverDim (Mover dimension in Y mm)
 * AccLimit (Acceleration Limit)
 * ErrorID (0x0001 = System Error, 0x2000 = Wrong PMC State, 0x2001 = No Mastership, 0x2002 = Mastership timeout,
 *		    0x2003 = Wrong group state, 0x2004 = Wrong Macro state, 0x2005 = Wrong Digital IO state,
 *          0x2006 = Wrong flyways state, 0x3000 = Wrong Xbot state, 0x4000 = Paramter Error: Invalid Parameters.
 *********************************************************************************)






FUNCTION_BLOCK PM_GetMoverProperties		
	// Check Reply
	IF(Busy)THEN
		brsmemcpy(ADR(CmdLbl),ADR(ReadFrame[3]),2);
		IF(ReadFrame[0] = CmdCount AND
			ReadFrame[1] 	= 30  AND
			ReadFrame[2]	= 11 AND
			CmdLbl = CmdLabel)THEN
			Done 	:= TRUE;
			Busy 	:= FALSE;
			brsmemcpy(ADR(ErrorID),ADR(ReadFrame[5]),2);
			Error 	:= UINT_TO_BOOL(ErrorID);
			Done 	:= NOT(UINT_TO_BOOL(ErrorID));
			
			brsmemcpy(ADR(MoverType),ADR(ReadFrame[7]),4);
			brsmemcpy(ADR(PayloadWeight),ADR(ReadFrame[11]),4);
			brsmemcpy(ADR(UserConfigCG),ADR(ReadFrame[15]),4);
			brsmemcpy(ADR(XMoverDim),ADR(ReadFrame[19]),4);
			brsmemcpy(ADR(YMoverDim),ADR(ReadFrame[27]),4);
			brsmemcpy(ADR(AccLimit),ADR(ReadFrame[35]),4);
			
			XMoverDim 		:= XMoverDim*1000.0;
			YMoverDim 		:= YMoverDim*1000.0;
			PayloadWeight 	:= PayloadWeight*1000.0;
			UserConfigCG	:= UserConfigCG*1000.0; 
			
			
			
		ELSE
			Busy := FALSE;
		END_IF;
	END_IF;
	//Send Command		
	IF(Execute AND NOT(Done) AND NOT(Error))THEN
		IF(NOT(Busy))THEN
			brsmemset(ADR(MsgFrame[1]),FALSE,98);
			CmdCount 		:= ReadFrame[0] +1;
			MsgFrame[0] 	:= CmdCount; 
			MsgFrame[1] 	:= 30;
			MsgFrame[2] 	:= 11;
			brsmemcpy(ADR(MsgFrame[3]), ADR(CmdLabel), 2);
			MsgFrame[5]		:= 1;
			MsgFrame[11]	:= XbotID; 
			Busy := TRUE;	
		END_IF;
		
	//Reset output status	
	ELSIF(NOT(Execute))THEN
		Busy := FALSE;
		Done := FALSE;
		Error := FALSE;
		ErrorID := 0;
	END_IF
	
	
	
END_FUNCTION_BLOCK
